//SUBMIT   EXEC PGM=IKJEFT1B,COND=(0,NE),PARM='%LAUNCH'
//SYSPROC  DD  DISP=SHR,DSN=набор данных с процедурой LAUNCH
//JCLLIB      DD  DISP=SHR,DSN=набор данных с заданиями
//INTRDR     DD  SYSOUT=(*,INTRDR)
//SYSTSIN   DD  DUMMY
//SYSTSPRT DD  SYSOUT=*

/* REXX Submit the next job from sequence if any */
parse upper arg .
cc = 16
/* Find the data set allocated to SYSPROC DD */
call outtrap 'stem.'
'LISTALC STATUS'
call outtrap 'off'
i = 2
dd.0 = 0
do while i < stem.0
       parse var stem.i dsname ddname disp
       i = i + 1
       select
       when dsname = 'NULLFILE'
       then nop
       when dsname = 'TERMFILE'
       then nop
       otherwise
          parse var stem.i 3 ddname +8 disp
          i = i + 1
       end
       if ddname = ''
       then do
          n = dd.0
          dd.n = dd.n "'"dsname"'"
          end
       else do
          n = dd.0 + 1
          dd.n = ddname "'"dsname"'"
          dd.0 = n
          end
end
found = 0
target = 'JCLLIB'
do i = 1 to dd.0
       parse var dd.i ddname dsnames
       if ddname = target
       then do
          found = 1
          leave i
          end
end i
if found = 0
then do
       say 'DD name 'target' is missed'
       signal quit
       end
found = 0
if words(dsnames) <> 1
then do
       say 'DD name 'target' is invalid'
       signal quit
       end
quote = "'"
parse var dsnames (quote) jcllib (quote) .

/* Get the member list of JCLLIB */
members. = 0
call outtrap 'temp.'
"LISTDS '"jcllib"' MEMBER"
cc = rc
call outtrap 'off'
if cc <> 0
then do
       do i = 1 to temp.0
          say temp.i
       end
       signal quit
       end
/* Skip LISTDS header */
do n = 1 to temp.0 until temp.n = '--MEMBERS--'
end n
maxjobno = 0
/* create job list and find the max job no */
do i = n+1 to temp.0
       parse value temp.i 1 with jobname members.jobname
       jobno = right(jobname, 3)
       if datatype(jobno, 'W') = 1
       then maxjobno = max(maxjobno, jobno)
end i
drop temp.
/* Extract the jobname of the running job */
jobname = storage(c2x(storage(d2x(x2d(c2x(storage('224',4)))+x2d('AC')),4)),8)
jobname = strip(jobname)
jobno = right(jobname, 3)
/* Look if we really have the next job to submit */
if datatype(jobno, 'W') = 0
then do /* Normally never happens, jobnames should be *nnn */
       say 'Invalid job name of the running job 'jobname
       signal quit
       end
nextjob = ''
do i = jobno+1 to maxjobno
       nextjob = left(jobname, length(jobname)-3)''right(i, 3, '0')
       if members.nextjob = 1
       then leave /* next job present */
end i
if nextjob = ''
then do
       cc = 0
       signal quit /* Nothing to submit */
       end
/*
       To make this automatic job submission more safe, we would like to
       ensure that we submit exactly the job what we want to run. Check
       the job card to be ensure that this is really the expected job.
*/
"ALLOC FI(JCLLIB) DSN('"jcllib"("nextjob")') SHR"
if rc \= 0
then do
       say 'Unable to allocate 'jcllib', ALLOCATE return code is 'rc
       signal quit
       end
'EXECIO * DISKR JCLLIB (FINIS STEM JOBCARDS.'
if rc \= 0
then do
       say 'Unable to read job from 'nextjob', EXECIO return code is 'rc
       signal quit
       end
parse var jobcards.1 '//' truename job .
if job \= 'JOB'
then do
       say 'The first card of member 'nextjob' is not a job card'
       signal quit
       end
if truename \= nextjob
then do
       say 'The jobname 'truename' is not the same as member name 'nextjob
       signal quit
       end
'FREE FI(JCLLIB)'
'EXECIO 'jobcards.0' DISKW INTRDR (FINIS STEM JOBCARDS.'
cc = rc
if rc = 0
then say 'Job 'nextjob' submitted'
Quit:
       exit cc

/* REXX  */
      ...
      c=0
      c=c+1;jcl.c="//"jobname" JOB ..."
      c=c+1;jcl.c="//STEP1  EXEC PGM=..."
      c=c+1;jcl.c="//SYSTSPRT DD SYSOUT=*"
...
      c=c+1;jcl.c="//STEP2 EXEC PGM=IEBGENER,COND=(16,LE,STEP1)"
      c=c+1;jcl.c="//SYSIN DD DUMMY"
      c=c+1;jcl.c="//SYSUT1 DD *"
      c=c+1;jcl.c="HELO "smtphost
      c=c+1;jcl.c="MAIL FROM:<"smtpfrom">"
...
      c=c+1;jcl.c="MIME-VERSION: 1.0"
...
      c=c+1;jcl.c="<html>"
...
      c=c+1;jcl.c="</html>"
      c=c+1;jcl.c="//SYSUT2 DD SYSOUT=(B,"smtptask")"
      c=c+1;jcl.c="//SYSPRINT DD SYSOUT=*"
      jcl.0=c
      jobid = submit(jcl.)
...

<script>
create() {
...
window.open(".../REPORT.REXX","win");
</script>
...
<input type="button" class=BUTTON value="Create report" onclick="create()">