Пт, 29.03.2024, 02:54
Приветствую Вас Гость | RSS
Главная | автоматическая загрузка z/OS - Форум | Регистрация | Вход
Форма входа
Логин:
Пароль:
[ Новые сообщения · Участники · Правила форума · Поиск · RSS ]
  • Страница 1 из 1
  • 1
Форум » Технические форумы » Hercules » автоматическая загрузка z/OS (автоматическая загрузка z/OS с помощью HAO)
автоматическая загрузка z/OS
GregoryДата: Ср, 15.09.2021, 23:36 | Сообщение # 1
Генерал-майор
Группа: Доверенные
Сообщений: 479
Репутация: 22
Статус: Offline
я тут в соседней ветке упомянул HAO (Hercules Auometic Operator), вот решил выложить файл для полностью автоматической загрузки z/OS
z24.bat

Код
@echo off
set PATH=F:\Programs\Hyperion;%PATH%
set HERCULES_RC=z24.rc
hercules -f z24.cfg

z24.rc

Код
* herclogo D:\Programs\Hercules\hercules.logo
* Auto IPL z/OS using HAO
msg * Auto IPL z/OS using HAO
hao tgt HHC01018I 0:00C0 COMM: client 127.0.0.1 devtype 3270: connected
hao cmd ipl 0A00
* IPL when 0C0 (master console) connected
hao tgt .*IEA101A .*
hao cmd .00,U
hao tgt .*IXC289D .*
hao cmd .00,U
hao tgt .*IXC420D .*
hao cmd .00,I
hao tgt .*IEE389I .*
hao cmd .v cn(*),act
hao tgt .*IEE712I .*
hao cmd .v 0c0,console
hao tgt \*([0-9]{2};) \$HASP426 .*
hao cmd .$1,NOREQ
hao tgt \*([0-9]{2};) \$HASP454 .*
hao cmd .$1,Y
hao tgt \*([0-9]{2};) \$HASP441 .*
hao cmd .$1,Y
hao tgt .*EZZ4313I .*
hao cmd .S STARTUP,STCLIST='TSO WWW DB2A'
hao tgt .*EZY2702I .*
hao cmd .S HAOCLR
sh cmd /c start F:\Programs\wc3270\wc3270.exe -model 2 -localcp 1251 -charset cp880 localhost:3270 &

симп
возможно, кому-то пригодится. Может быть использован для других версий z/OS  других OS после соответствующей модификации

Примечание
hao cmd .S HAOCLR потому что реализация HAO запрещает выдавать команды HAO с помощью HAO. Как обычно, разработчики чего-либо считают, что весь окружающий мир состоит из идиотов, а они такие умные, что лучше знают, как надо. Тут бы надо написать просто
hao cmd hao clear

Код
//HAOCLR   PROC
//*********************************************************************
//* Function:  Clear all HAO rules
//* Syntax:    S HAOCLR
//*********************************************************************
//HOSTCMD  EXEC PGM=HOSTCMD,PARM='hao clear'
//STEPLIB  DD DISP=SHR,DSN=CPAC.LINKLIB

HOSTCMD см.https://www.cbttape.org/cbtdowns.htm файл 845. BTW. я до сих пор не знаю, кто это выложил) я это туда не выкладывал

Код
//STARTUP  PROC STCLIST=
//STARTUP  EXEC PGM=IKJEFT01,PARM='%STARTUP &STCLIST'
//SYSEXEC  DD  DISP=SHR,DSN=CPAC.CMDPROC
//SYSTSPRT DD  SYSOUT=*
//SYSPRINT DD  SYSOUT=*
//SYSTSIN  DD  DUMMY
//


Код
/* REXX */
/*

Function:
         This Exec performs a startup of the z/OS system

Syntax:
         Should ran as STC via STARTUP procedure

Note:    The userid which is running this Exec must have RACF
         OPERPARM settings like the following:
         ALTUSER xxxx OPERPARM(AUTH(ALL) ROUTCODE(ALL))

*/
trace off
parse upper arg stclist
say 'STARTUP 'stclist
msg_stat = msg('off')

'CONSPROF SOLDISP(NO) SOLNUM(500)'
'CONSOLE ACTIVATE'
cart = 1
say ''
say left('Id',8) left('Command', 60) 'RC'
say copies('-',8) copies('-', 60) copies('-', 4)
rc = syscmd('EREP', 'S EREP')
rc = syscmd('ASCH', 'S ASCH,SUB=MSTR')
rc = syscmd('TCPIP', 'S TCPIP')
rc = syscmd('CFZ', 'S CFZCIM')
rc = syscmd('ICSF', 'S CSF')
rc = syscmd('RRS', 'S RRS,SUB=MSTR')
rc = syscmd('TSO', 'S TSO')

/* DB2 */
rc = syscmd('DB2A', '-A START DB2')
rc = syscmd('DB2B', '-B START DB2')

/* WebServer */
rc = syscmd('WWW', 'S WEBSRV')
say ''

'CONSOLE DEACTIVATE'
exit 0

syscmd:
  parse arg name, cmd
  rc = -1
  if wordpos(name, stclist) > 0
  then 'CONSOLE SYSCMD('cmd') CART(STRT00'right(cart, 2, '0')')'
  cart = cart + 1
  say left(name,8) left(cmd, 60) rc
  return rc


Сообщение отредактировал Gregory - Чт, 16.09.2021, 00:03
 
Форум » Технические форумы » Hercules » автоматическая загрузка z/OS (автоматическая загрузка z/OS с помощью HAO)
  • Страница 1 из 1
  • 1
Поиск: